ぼんぷろぐ

InDesignとかイラレとかのスクリプトよもやま話

新しいブログに引っ越しました。

こちらのブログはもう更新しませんが、コメント欄は生きてますので疑問、ご指摘などありましたらどうぞ。

[AutoHotkey]
AutoHotkeyでAcrobatをいじる2：画像ファイルからpdf作成

前回に引き続いて、AutoHotkeyでドロップレット（.ahkファイルに処理したいファイルをドラッグ＆ドロップして動かすタイプのスクリプト）を作ってみます。

まずは画像からpdfを作成するドロップレット

Loop,%0%
Loop,% %A_Index%
{
    path:=A_LoopFileLongPath
    ext:=A_LoopFileExt
    pathNoExt:=SubStr(path,1,-StrLen(ext)-1)
    newPdfPath=%pathNoExt%.pdf
    IfExist,%newPdfPath%
    Loop
    {
        newPdfPath=%pathNoExt%(%A_Index%).pdf
        IfNotExist,%newPdfPath%
            Break
    }

    avd:=ComObjCreate("AcroExch.AVDoc")
    result:=avd.Open(path,"")
    If result=-1
    {
        avd.GetPDDoc().Save(1,newPdfPath)
        avd.Close(1)
    }
}

Acrobatのファイルメニューにある「画像からpdf」を自動化するものです。
JPEG,PNGなどAcrobatが対応してる画像ファイルならなんでもいけます。
複数ファイルを同時にドロップした場合は、それぞれ別のpdfになります。

ちょっと解説
例によって最初の２行はおまじないとしまして、
path:=A_LoopFileLongPath
ext:=A_LoopFileExt
pathNoExt:=SubStr(path,1,-StrLen(ext)-1)
newPdfPath=%pathNoExt%.pdf
IfExist,%newPdfPath%
Loop
{
    newPdfPath=%pathNoExt%(%A_Index%).pdf
    IfNotExist,%newPdfPath%
        Break
}
ここらへんは保存するpdfファイルのパス文字列を用意しています。
同名ファイルがあれば上書きしないように(1)をつけて、それもあれば(2)をつけて…という処理です。
AHKの:=と=の使い分けを知らない人は何だコレってなるかも。（参考→AutoHotkey wiki：言語仕様）

あとはAcrobat OLEのAVDocで開いて、開くのに成功したら保存して閉じる、という流れです。
なぜか知らないけど画像を開けるのはPDDocでなくAVDocだけのようです。

ちゅぎ

今度は複数の画像ファイルをドロップしたとき、それらをまとめて１つのpdfファイルにするやつ
いわばAcrobatのメニューにある「ファイルを単一のpdfに結合」の自動化です。

Loop,%1%
{
path:=A_LoopFileLongPath
ext:=A_LoopFileExt
pathNoExt:=SubStr(path,1,-StrLen(ext)-1)

newPdfPath=%pathNoExt%.pdf
IfExist,%newPdfPath%
Loop
{
    newPdfPath=%pathNoExt%(%A_Index%).pdf
    IfNotExist,%newPdfPath%
        Break
}

pdd0:=ComObjCreate("AcroExch.PDDoc")
pdd0.Create()

Loop,%0%
Loop,% %A_Index%
{
    path:=A_LoopFileLongPath
    avd1:=ComObjCreate("AcroExch.AVDoc")
    result:=avd1.Open(path,"a")
    If result=-1
    {
        pdd1:=avd1.GetPDDoc()
        pdd0.InsertPages(-2,pdd1,0,1,0)
        avd1.Close(1)
    }
}
pdd0.Save(1,newPdfPath)
pdd0.Close()
}

えー12行目あたりまでは上のと同じ保存するファイルパスの用意ですね。

pdd0:=ComObjCreate("AcroExch.PDDoc")
pdd0.Create()
でPDDocのドキュメントを新規作成して、

AVDocで画像をpdf化して、そのページを新規作成したドキュメントに追加していく、という手順です。
このへんはpdf-file.nnn2.comさんの、こちらのコメント欄がとても参考になりました。ありがたやありがたや。

続くかも？

[AutoHotkey]
AutoHotkeyでAcrobatをいじる話

AutoHotkey（略称：AHK）でアプリを操作といえば、キー入力を送ったり特定の位置にマウスクリックを発生させたりというようなのがAHKの得意とするところなのですが、今回はそういうのではなく、OLEあるいはCOMと呼ばれる仕組みを使ってAcrobatとやりとりする話です。VBSでやれと言われそうですけど、案外書きやすいんです、AHKスクリプト。

AHKを公式のインストーラーでインストールすると、エクスプローラー上で.ahkファイルに対して任意のファイルをドラッグ＆ドロップして、そのファイルについての処理をすることができます。adobeユーザーにはこういうの『ドロップレット』っていう言葉で定着してるのかな？私は最近まで知らなかったけど。

たとえばこんなのができます。

D&Dしたpdfのタイトルをファイル名（拡張子除く）にして、作成者名を空欄にして上書き保存するドロップレット

Loop,%0%
Loop,% %A_Index%
{
name:=A_LoopFileName
path:=A_LoopFileLongPath
d:=ComObjCreate("AcroExch.PDDoc")
d.Open(path)
d.SetInfo("Title",SubStr(name,1,-4))
d.SetInfo("Author","")
d.Save(0,path)
d.Close()
}
MsgBox,完了！

えー、スクリプトの解説をしようと思うんですが、まず最初の2行が超説明しづらいのでおまじないと思ってください。これにより以下の"{"から"}"までが、D&Dしたファイルの個数分ループします。

ループの中では、A_LoopFileNameという変数にD&Dしたファイルの名前が入っています。
２回目のループでは２つ目のファイル、３回目のループでは３つ目のファイル…です。便利ですね。
ファイル名以外にもいろいろ取得できます（→AutoHotkey Wiki）。

d:=ComObjCreate("AcroExch.PDDoc")
でAcrobatのPDDocオブジェクトを生成します。
AcrobatのドキュメントオブジェクトはPDDocとAVDocの２つがあるんですが、AVDocは主にドキュメントの画面表示に関することなので今回は使いません。

PDDocのメソッドについては pdf-file.nnn2.com にすばらしい解説があるので、AHKだとこれくらいシンプルに書けるよーということ以外、特に言うことはありません。

なお、昔AHKをインストールして、ドロップレットにできないって人もいるかもしれません。私もいつかのWindowsアップデートでできなくなりました。再インストールすればできるようになるはずです。

つぎはもう少しAHKらしい使い方をしてみます。常駐させてホットキーで動作するタイプのAHKスクリプト。

Acrobatでpdfファイルを開いている状態で、
・F1を押すと、Acrobatで現在開いているファイルをエクスプローラーで参照
・F2を押すと、Acrobatで現在開いているファイルをデスクトップにコピー
できるようにします。

#IfWinActive ahk_class AcrobatSDIWindow

F1::
filePath:=getAcrobatActiveFilePath()
Run,explorer /select`,%filePath%
Return

F2::
MsgBox,4,,pdfをデスクトップにコピーしますか？
IfMsgBox, Yes
{
filePath:=getAcrobatActiveFilePath()
FileCopy, %filePath%, %A_Desktop%\
}
Return

getAcrobatActiveFilePath(){
f:=ComObjCreate("AcroExch.App").GetActiveDoc().GetPDDoc().GetJSObject().path
f:=RegExReplace(f,"^/(.)/","$1:/")
f:=RegExReplace(f,"^/(.+?)/","//$1/")
f:=RegExReplace(f,"/","\")
Return f
}

今回はAcrobatには開いているファイルのパスを教えてもらうだけなんですが、これが意外と大変でした。

Acrobat OLEのメソッドやプロパティは pdf-file.nnn2.comさんの「オブジェクトの連携図」に網羅されているのですが、ここにファイルパスらしいものが見つからないのです。

しかし、AcrobatにはOLEとは別にJavaScriptによる自動化があります。そしてこのJavaScriptと同等のことができることになっている（が実際はそんなにできない）JSObjectというものにOLEからもアクセスできるようになっています。

f:=ComObjCreate("AcroExch.App").GetActiveDoc().GetPDDoc().GetJSObject().path

で、AcrobatのAppオブジェクトから、アクティブなドキュメントのAVDocオブジェクトを取得して、それに関連付けられたPDDocオブジェクトを取得して、そのJSObjectを取得し、そこからパスを取得しています。
ほんとにこんな回りくどいことをしなくちゃいけないのか、定かではないんですが…

ほかの部分を簡単に解説すると、
#IfWinActive ahk_class AcrobatSDIWindow
これは「以下のホットキーをAcrobatのウインドウがアクティブのときだけ有効にする」という意味。

F1::
から
Return
までがF1キーが押されたとき呼ばれるサブルーチン。

MsgBoxは１つ目の引数でタイプを指定できて、4だと「はい」「いいえ」のボタンがあるダイアログになります。
IfMsgBoxは直前のMsgBoxで押されたボタンにより分岐します。

続くかも？