中ボタンでいつでも手のひらツールを発展させて、片手のマウスだけでInDesignドキュメントを眺めるのに必要な一通りの機能が使えるようにしてみました。
・中ボタンドラッグで手のひらツール
・中ボタンダブルクリックでスプレッド全体を表示
・右ボタン押しながらスクロールで拡大縮小
・右ボタン押しながら左クリックで「プレビュー←→通常」の切り替え
以下AHKスクリプトのソース
IdProgId=InDesign.Application
DoubleClickDelay:=300
SetMouseDelay, -1
SetKeyDelay, -1
MButtonDownTime1:=0
Return
#IfWinActive ahk_class indesign
;中ボタン押し下げ
*MButton::
BlockInput, on
MButtonDownTime0:=MButtonDownTime1
MButtonDownTime1:=A_TickCount
If (MButtonDownTime1-MButtonDownTime0<DoubleClickDelay){
Send ^!0
Return
}
Send {Blind}{Alt Down}
Send {Blind}{Space Down}
Send {Blind}{LButton Down}
BlockInput, off
Return
;中ボタン押し上げ
*MButton up::
BlockInput, on
Send {Blind}{LButton Up}
Send {Blind}{Space Up}
Send {Blind}{Alt Up}
BlockInput, off
Return
;右ボタン＋スクロール
RButton & WheelUp::
Send !{WheelUp}
Return
RButton & WheelDown::
Send !{WheelDown}
Return
;右ボタン＋左ボタン
RButton & LButton::
app:=ComObjCreate(IdProgId)
if (app.menuActions.itemByID(118830).checked=-1)
app.menuActions.itemByID(118829).invoke()
Else
app.menuActions.itemByID(118830).invoke()
Return
;右ボタンがそのまま離された
RButton::
MouseClick ,R
Return
つかいかた
上記のスクリプトをテキストファイル（UTF-8 BOM付き）で保存して、拡張子をahkにしてAutoHotkeyで実行します。
※環境によっては
IdProgId=InDesign.Application
のところを
IdProgId=InDesign.Application.CS6_J
などと書き換えなくてはならないかもしれません
単体で動作するEXEファイル版のダウンロードは
こちら
PR
